From 170009b12326a66fe02963e223e5648603bc2488 Mon Sep 17 00:00:00 2001
From: wucke13 <wucke13@gmail.com>
Date: Wed, 7 Nov 2018 14:24:19 +0100
Subject: [PATCH] betaflight-configurator: init at 10.5.1

---
 .../betaflight-configurator/default.nix       | 53 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 55 insertions(+)
 create mode 100644 pkgs/applications/science/robotics/betaflight-configurator/default.nix

diff --git a/pkgs/applications/science/robotics/betaflight-configurator/default.nix b/pkgs/applications/science/robotics/betaflight-configurator/default.nix
new file mode 100644
index 00000000000..10181a7b1fd
--- /dev/null
+++ b/pkgs/applications/science/robotics/betaflight-configurator/default.nix
@@ -0,0 +1,53 @@
+{stdenv, fetchurl, unzip, runtimeShell, makeDesktopItem, nwjs }:
+
+let
+  strippedName = "betaflight-configurator";
+  desktopItem = makeDesktopItem {
+    name = strippedName;
+    exec = strippedName;
+    icon = "${strippedName}-icon.png";
+    comment = "Betaflight configuration tool";
+    desktopName = "Betaflight Configurator";
+    genericName = "Flight controller configuration tool";
+  };
+in
+stdenv.mkDerivation rec {
+  name = "${strippedName}-${version}";
+  version = "10.5.1";
+  src = fetchurl {
+    url = "https://github.com/betaflight/betaflight-configurator/releases/download/${version}/${strippedName}_${version}_linux64.zip";
+    sha256 = "1l4blqgaqfrnydk05q6pwdqdhcly2f8nwzrv0749cqmfiinh8ygc";
+  };
+
+  buildInputs = [ unzip ];
+  
+  installPhase = ''
+    mkdir -p $out/bin \
+             $out/opt/${strippedName} \
+             $out/share/icons
+
+    cp -r . $out/opt/${strippedName}/
+    cp icon/*_icon_128.png $out/share/icons/${strippedName}-icon.png
+    cp -r ${desktopItem}/share/applications $out/share/
+
+    cat >$out/bin/${strippedName}<<EOL
+    #!${runtimeShell}
+
+    ${nwjs}/bin/nw $out/opt/${strippedName} 
+    EOL
+    chmod +x $out/bin/${strippedName}
+  '';
+
+  meta = with stdenv.lib; {
+    description = "The Betaflight flight control system configuration tool";
+    longDescription = ''
+      A crossplatform configuration tool for the Betaflight flight control system.
+      Various types of aircraft are supported by the tool and by Betaflight, e.g. 
+      quadcopters, hexacopters, octocopters and fixed-wing aircraft.
+    '';
+    homepage    = https://github.com/betaflight/betaflight/wiki;
+    license     = licenses.gpl3;
+    maintainers = with maintainers; [ wucke13 ];
+    platforms   = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 9954f6ff441..295aae465d0 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -22983,6 +22983,8 @@ in
 
   apmplanner2 = libsForQt511.callPackage ../applications/science/robotics/apmplanner2 { };
 
+  betaflight-configurator = callPackage ../applications/science/robotics/betaflight-configurator { };
+
   ### MISC
 
   acpilight = callPackage ../misc/acpilight { };