r2, r2-cutter: refactor and bump cutter to 1.7

2018-08-21 18:22:38 -05:00
parent ec7af525ba
commit 2957313356
5 changed files with 116 additions and 94 deletions
@@ -0,0 +1,54 @@
+{ stdenv, fetchFromGitHub
+# nativeBuildInputs
+, qmake, pkgconfig
+# Qt
+, qtbase, qtsvg, qtwebengine
+# buildInputs
+, r2-for-cutter
+, python3 }:
+
+let
+  version = "1.7";
+in
+stdenv.mkDerivation rec {
+  name = "radare2-cutter-${version}";
+
+  src = fetchFromGitHub {
+    owner = "radareorg";
+    repo = "cutter";
+    rev = "v${version}";
+    sha256 = "0z9wzxd5hw0ivakrg3xiv4zx1rjj032hlmizq0pxj22xjrj1gg9n";
+  };
+
+  postUnpack = "export sourceRoot=$sourceRoot/src";
+
+  # Remove this "very helpful" helper file intended for discovering r2,
+  # as it's a doozy of harddcoded paths and unexpected behavior.
+  # Happily Nix has everything all set so we don't need it,
+  # other than as basis for the qmakeFlags set below.
+  postPatch = ''
+    substituteInPlace Cutter.pro \
+      --replace "include(lib_radare2.pri)" ""
+  '';
+
+  nativeBuildInputs = [ qmake pkgconfig ];
+  buildInputs = [ qtbase qtsvg qtwebengine r2-for-cutter python3 ];
+
+  qmakeFlags = [
+    "CONFIG+=link_pkgconfig"
+    "PKGCONFIG+=r_core"
+    # Leaving this enabled doesn't break build but generates errors
+    # at runtime (to console) about being unable to load needed bits.
+    # Disable until can be looked at.
+    "CUTTER_ENABLE_JUPYTER=false"
+  ];
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    description = "A Qt and C++ GUI for radare2 reverse engineering framework";
+    homepage = src.meta.homepage;
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ dtzWill ];
+  };
+}
@@ -1,82 +1,16 @@
-{stdenv, fetchFromGitHub
-, ninja, meson , pkgconfig
-, libusb, readline, libewf, perl, zlib, openssl
-, gtk2 ? null, vte ? null, gtkdialog ? null
-, python ? null
-, ruby ? null
-, lua ? null
-, useX11, rubyBindings, pythonBindings, luaBindings
-}:
+{ callPackage, ...} @ args:

-assert useX11 -> (gtk2 != null && vte != null && gtkdialog != null);
-assert rubyBindings -> ruby != null;
-assert pythonBindings -> python != null;
-
-
-let
-  inherit (stdenv.lib) optional;
+callPackage ./generic.nix (args // {
  #<generated>
  # DO NOT EDIT! Automatically generated by ./update.py
-  version_commit = "19004";
-  gittap = "2.8.0";
-  gittip = "a76b965410aba07b4ef8b96d90b25b271c2003dd";
-  version = "2.8.0";
-  sha256 = "1d9rkzc3vychy2h1bnywwx4why83rr18r0lvvl1cqx87ad5awcjk";
-  cs_tip = "782ea67e17a391ca0d3faafdc365b335a1a8930a";
-  cs_sha256 = "1maww4ir78a193pm3f8lr2kdkizi7rywn68ffa65ipyr7j4pl6i4";
+  src_info = {
+    version_commit = "19004";
+    gittap = "2.8.0";
+    gittip = "a76b965410aba07b4ef8b96d90b25b271c2003dd";
+    version = "2.8.0";
+    sha256 = "1d9rkzc3vychy2h1bnywwx4why83rr18r0lvvl1cqx87ad5awcjk";
+    cs_tip = "782ea67e17a391ca0d3faafdc365b335a1a8930a";
+    cs_sha256 = "1maww4ir78a193pm3f8lr2kdkizi7rywn68ffa65ipyr7j4pl6i4";
+  };
  #</generated>
-in
-stdenv.mkDerivation rec {
-  name = "radare2-${version}";
-
-  src = fetchFromGitHub {
-    owner = "radare";
-    repo = "radare2";
-    rev = version;
-    inherit sha256;
-  };
-
-  postPatch = let
-    capstone = fetchFromGitHub {
-      owner = "aquynh";
-      repo = "capstone";
-      # version from $sourceRoot/shlr/Makefile
-      rev = cs_tip;
-      sha256 = cs_sha256;
-    };
-  in ''
-    if ! grep -F "CS_TIP=${cs_tip}" shlr/Makefile; then echo "CS_TIP mismatch"; exit 1; fi
-    # When using meson, it expects capstone source relative to build directory
-    mkdir -p build/shlr
-    ln -s ${capstone} build/shlr/capstone
-  '';
-
-  postInstall = ''
-    ln -s $out/bin/radare2 $out/bin/r2
-    install -D -m755 $src/binr/r2pm/r2pm $out/bin/r2pm
-  '';
-
-  mesonFlags = [
-    "-Dr2_version_commit=${version_commit}"
-    "-Dr2_gittap=${gittap}"
-    "-Dr2_gittip=${gittip}"
-  ];
-
-  enableParallelBuilding = true;
-
-  nativeBuildInputs = [ pkgconfig ninja meson ];
-  buildInputs = [ readline libusb libewf perl zlib openssl]
-    ++ optional useX11 [gtkdialog vte gtk2]
-    ++ optional rubyBindings [ruby]
-    ++ optional pythonBindings [python]
-    ++ optional luaBindings [lua];
-
-  meta = {
-    description = "unix-like reverse engineering framework and commandline tools";
-    homepage = http://radare.org/;
-    license = stdenv.lib.licenses.gpl2Plus;
-    maintainers = with stdenv.lib.maintainers; [raskin makefu mic92];
-    platforms = with stdenv.lib.platforms; linux;
-    inherit version;
-  };
-}
+})
@@ -0,0 +1,75 @@
+{stdenv, fetchFromGitHub
+, src_info, callPackage
+, ninja, meson , pkgconfig
+, libusb, readline, libewf, perl, zlib, openssl
+, gtk2 ? null, vte ? null, gtkdialog ? null
+, python ? null
+, ruby ? null
+, lua ? null
+, useX11, rubyBindings, pythonBindings, luaBindings
+}:
+
+assert useX11 -> (gtk2 != null && vte != null && gtkdialog != null);
+assert rubyBindings -> ruby != null;
+assert pythonBindings -> python != null;
+
+
+let
+  inherit (stdenv.lib) optional;
+in stdenv.mkDerivation (with src_info; rec {
+  name = "radare2-${version}";
+
+  src = fetchFromGitHub {
+    owner = "radare";
+    repo = "radare2";
+    rev = version;
+    inherit sha256;
+  };
+
+  postPatch = let
+    capstone = fetchFromGitHub {
+      owner = "aquynh";
+      repo = "capstone";
+      # version from $sourceRoot/shlr/Makefile
+      rev = cs_tip;
+      sha256 = cs_sha256;
+    };
+  in ''
+    if ! grep -F "CS_TIP=${cs_tip}" shlr/Makefile; then echo "CS_TIP mismatch"; exit 1; fi
+    # When using meson, it expects capstone source relative to build directory
+    mkdir -p build/shlr
+    ln -s ${capstone} build/shlr/capstone
+  '';
+
+  postInstall = ''
+    ln -s $out/bin/radare2 $out/bin/r2
+    install -D -m755 $src/binr/r2pm/r2pm $out/bin/r2pm
+  '';
+
+  mesonFlags = [
+    "-Dr2_version_commit=${version_commit}"
+    "-Dr2_gittap=${gittap}"
+    "-Dr2_gittip=${gittip}"
+    # 2.8.0 expects this, but later it becomes an option with default=false.
+    "-Dcapstone_in_builddir=true"
+  ];
+
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [ pkgconfig ninja meson ];
+  buildInputs = [ readline libusb libewf perl zlib openssl]
+    ++ optional useX11 [gtkdialog vte gtk2]
+    ++ optional rubyBindings [ruby]
+    ++ optional pythonBindings [python]
+    ++ optional luaBindings [lua];
+
+  meta = {
+    description = "unix-like reverse engineering framework and commandline tools";
+    homepage = http://radare.org/;
+    license = stdenv.lib.licenses.gpl2Plus;
+    maintainers = with stdenv.lib.maintainers; [raskin makefu mic92];
+    platforms = with stdenv.lib.platforms; linux;
+    inherit version;
+  };
+})
+
@@ -0,0 +1,16 @@
+{ callPackage, ...} @ args:
+
+callPackage ./generic.nix (args // {
+  #<generated>
+  # DO NOT EDIT! Automatically generated by ./update.py
+  src_info = {
+    version_commit = "19256";
+    gittap = "2.8.0-118-gb0547831f";
+    gittip = "b0547831f127b7357e3c93bc43933482a4d6213b";
+    version = "2.9.0-git";
+    sha256 = "1ix42kipd1aayb494ajbxawzc1cwikm9fxk343d1kchxx4a30a1m";
+    cs_tip = "782ea67e17a391ca0d3faafdc365b335a1a8930a";
+    cs_sha256 = "1maww4ir78a193pm3f8lr2kdkizi7rywn68ffa65ipyr7j4pl6i4";
+  };
+  #</generated>
+})