add tk-8_5 and fix xconq (XHF)

2015-06-19 16:06:10 +02:00
parent ffb70f9c51
commit 6551af69eb
4 changed files with 34 additions and 9 deletions
@@ -0,0 +1,40 @@
+{ stdenv, src, pkgconfig, tcl, libXft, fontconfig, patches ? [], ... }:
+
+stdenv.mkDerivation {
+  name = "tk-${tcl.version}";
+
+  inherit src patches;
+
+  postInstall = ''
+    ln -s $out/bin/wish* $out/bin/wish
+  '';
+
+  preConfigure = ''
+    cd unix
+  '';
+
+  configureFlags = [
+    "--with-tcl=${tcl}/lib"
+  ];
+
+  buildInputs = [ pkgconfig tcl libXft ]
+    ++ stdenv.lib.optional stdenv.isDarwin fontconfig;
+
+  NIX_CFLAGS_LINK = if stdenv.isDarwin then "-lfontconfig" else null;
+
+  inherit tcl;
+
+  passthru = rec {
+    inherit (tcl) release version;
+    libPrefix = "tk${tcl.release}";
+    libdir = "lib/${libPrefix}";
+  };
+
+  meta = with stdenv.lib; {
+    description = "A widget toolkit that provides a library of basic elements for building a GUI in many different programming languages";
+    homepage = http://www.tcl.tk/;
+    license = licenses.tcltk;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ lovek323 wkennington ];
+  };
+}