add kde-applications-14.12.1

pkgs/applications/kde-apps-14.12/default.nix

@@ -0,0 +1,170 @@
+{ autonix, kde4, kf55, pkgs, qt4, stdenv, debug ? false }:
+
+with stdenv.lib; with autonix;
+
+let
+
+  kf5 = kf55.override { inherit debug; };
+
+  mirror = "mirror://kde";
+
+  renames =
+    builtins.removeAttrs
+      (import ./renames.nix {})
+      ["Backend" "CTest"];
+
+  scope =
+    # packages in this collection
+    (mapAttrs (dep: name: kdeApps."${name}") renames) //
+    # packages from KDE Frameworks 5
+    kf5.scope //
+    # packages from nixpkgs
+    (with pkgs;
+      {
+        Alsa = alsaLib;
+        Cdparanoia = cdparanoia;
+        CUPS = cups;
+        DjVuLibre = djvulibre;
+        EPub = ebook_tools;
+        Eigen2 = eigen2;
+        Eigen3 = eigen;
+        Exiv2 = exiv2;
+        FFmpeg = ffmpeg;
+        Flac = flac;
+        Freetype = freetype;
+        GMP = gmp;
+        Gettext = gettext;
+        Gpgme = gpgme;
+        Gphoto2 = libgphoto2;
+        Grantlee = grantlee;
+        GSL = gsl;
+        HUNSPELL = hunspell;
+        KActivities = kde4.kactivities;
+        KDE4 = kde4.kdelibs;
+        KDE4Workspace = kde4.kde_workspace;
+        Kexiv2 = kdeApps.libkexiv2;
+        Kdcraw = kdeApps.libkdcraw;
+        KdepimLibs = kde4.kdepimlibs;
+        Kipi = kdeApps.libkipi;
+        LCMS2 = lcms2;
+        LibAttica = attica;
+        LibGcrypt = libgcrypt;
+        LibKMahjongg = kdeApps.libkmahjongg;
+        LibKonq = kdeApps.kde-baseapps;
+        LibSSH = libssh;
+        LibSpectre = libspectre;
+        LibVNCServer = libvncserver;
+        MusicBrainz3 = libmusicbrainz;
+        NetworkManager = networkmanager;
+        OggVorbis = libvorbis;
+        OpenAL = openal;
+        OpenEXR = openexr;
+        Poppler = poppler.poppler_qt4;
+        PulseAudio = pulseaudio;
+        Qalculate = libqalculate;
+        QCA2 = qca2;
+        Samba = samba;
+        SndFile = libsndfile;
+        Speechd = speechd;
+        TIFF = libtiff;
+        Taglib = taglib;
+        TelepathyQt4 = telepathy_qt;
+        TunePimp = libtunepimp;
+        Xscreensaver = xscreensaver;
+      }
+    );
+
+  preResolve = super:
+    fold (f: x: f x) super
+      [
+        (userEnvPkg "SharedMimeInfo")
+        (userEnvPkg "SharedDesktopOntologies")
+        (blacklist ["artikulate"]) # build failure, wrong boost?
+        (blacklist ["kde-dev-scripts" "kde-dev-utils"]) # docbook errors
+        (blacklist ["kdewebdev"]) # unknown build failure
+      ];
+
+  postResolve = super:
+    super // {
+
+      ffmpegthumbs = with pkgs; super.ffmpegthumbs // {
+        nativeBuildInputs = super.ffmpegthumbs.nativeBuildInputs ++ [pkgconfig];
+      };
+
+      kalzium = with pkgs; super.kalzium // {
+        nativeBuildInputs = super.kalzium.nativeBuildInputs ++ [pkgconfig];
+      };
+
+      kde-runtime = with pkgs; super.kde-runtime // {
+        buildInputs =
+          super.kde-runtime.buildInputs ++ [libcanberra];
+        nativeBuildInputs =
+          super.kde-runtime.nativeBuildInputs ++ [pkgconfig];
+        NIX_CFLAGS_COMPILE =
+          (super.kde-runtime.NIX_CFLAGS_COMPILE or "")
+          + " -I${ilmbase}/include/OpenEXR";
+      };
+
+      kdesdk-thumbnailers = with pkgs; super.kdesdk-thumbnailers // {
+        nativeBuildInputs =
+          super.kdesdk-thumbnailers.nativeBuildInputs
+          ++ [gettext];
+      };
+
+      kgpg = with pkgs; super.kgpg // {
+        buildInputs = super.kgpg.buildInputs ++ [boost];
+      };
+
+      kmix = with pkgs; super.kmix // {
+        nativeBuildInputs = super.kmix.nativeBuildInputs ++ [pkgconfig];
+      };
+
+      kmousetool = with pkgs; super.kmousetool // {
+        buildInputs = with xlibs;
+          super.kmousetool.buildInputs
+          ++ [libXtst libXt];
+      };
+
+      kremotecontrol = with pkgs; super.kremotecontrol // {
+        buildInputs = super.kremotecontrol.buildInputs ++ [xlibs.libXtst];
+      };
+
+      krfb = with pkgs; super.krfb // {
+        buildInputs =
+          super.krfb.buildInputs
+          ++ [xlibs.libXtst kde4.telepathy.common_internals];
+      };
+
+      libkdcraw = with pkgs; super.libkdcraw // {
+        buildInputs = super.libkdcraw.buildInputs ++ [kde4.kdelibs libraw];
+        nativeBuildInputs = super.libkdcraw.nativeBuildInputs ++ [pkgconfig];
+      };
+
+      libkexiv2 = with pkgs; super.libkexiv2 // {
+        buildInputs = super.libkexiv2.buildInputs ++ [exiv2 kde4.kdelibs];
+      };
+
+      libkface = with pkgs; super.libkface // {
+        buildInputs = super.libkface.buildInputs ++ [kde4.kdelibs opencv];
+      };
+
+      libkipi = with pkgs; super.libkipi // {
+        buildInputs = super.libkipi.buildInputs ++ [kde4.kdelibs];
+      };
+
+      libksane = with pkgs; super.libksane // {
+        buildInputs = super.libksane.buildInputs ++ [kde4.kdelibs saneBackends];
+      };
+
+      okular = with pkgs; super.okular // {
+        buildInputs = super.okular.buildInputs ++ [ebook_tools];
+      };
+
+    };
+
+  kdeApps = generateCollection ./. {
+    inherit (kf5) mkDerivation;
+    inherit mirror preResolve postResolve scope;
+  };
+
+in kdeApps

pkgs/applications/kde-apps-14.12/dependencies.sh

@@ -0,0 +1,12 @@
+#!/bin/sh
+
+manifestXML=$(nix-build -E 'with (import ../../.. {}); autonix.writeManifestXML ./manifest.nix')
+
+autonixDepsKf5=""
+if [[ -z $1 ]]; then
+    autonixDepsKF5=$(nix-build ../../.. -A haskellPackages.autonixDepsKf5)/bin
+else
+    autonixDepsKF5="$1/dist/build/kf5-deps"
+fi
+
+exec ${autonixDepsKF5}/kf5-deps "${manifestXML}"

pkgs/applications/kde-apps-14.12/manifest.sh

@@ -0,0 +1,15 @@
+#!/bin/sh
+
+if [ $# -eq 0 ]; then
+
+  # The extra slash at the end of the URL is necessary to stop wget
+  # from recursing over the whole server! (No, it's not a bug.)
+  $(nix-build ../../.. -A autonix.manifest) \
+      http://download.kde.org/stable/applications/14.12.0/ \
+      -A '*.tar.xz'
+
+else
+
+  $(nix-build ../../.. -A autonix.manifest) -A '*.tar.xz' "$@"
+
+fi

pkgs/applications/kde-apps-14.12/renames.nix

@@ -0,0 +1,18 @@
+# DO NOT EDIT! This file is generated automatically.
+{ }:
+{
+"Analitza5" = "analitza";
+"CTest" = "sweeper";
+"ECM" = "extra-cmake-modules";
+"JDns" = "kopete";
+"KDEGames" = "libkdegames";
+"KSane" = "libksane";
+"LibKEduVocDocument" = "libkeduvocdocument";
+"LibKdeEdu" = "libkdeedu";
+"LibKompareDiff2" = "libkomparediff2";
+"Libkcddb" = "libkcddb";
+"Libkcompactdisc" = "libkcompactdisc";
+"Okular" = "okular";
+"QJDns" = "kopete";
+"QMobipocket" = "kdegraphics-mobipocket";
+}

pkgs/applications/kde-apps-14.12/setup-hook.sh

@@ -0,0 +1 @@
+addToSearchPath XDG_DATA_DIRS @out@/share

pkgs/top-level/all-packages.nix

@@ -10364,6 +10364,11 @@ let
     boost = boost155;
   };
 
+  kdeApps_latest = kdeApps_14_12;
+  kdeApps_14_12 = recurseIntoAttrs (callPackage ../applications/kde-apps-14.12 {
+    stdenv = overrideGCC stdenv gccStdInc;
+  });
+
   keepnote = callPackage ../applications/office/keepnote {
     pygtk = pyGtkGlade;
   };