parity: 3.0.0 -> 3.0.1 and rename it to openethereum

pkgs/applications/blockchains/openethereum/default.nix

@@ -0,0 +1,50 @@
+{ lib
+, fetchFromGitHub
+, rustPlatform
+, cmake
+, llvmPackages
+, openssl
+, pkg-config
+, systemd
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "openethereum";
+  version = "3.0.1";
+
+  src = fetchFromGitHub {
+    owner = "openethereum";
+    repo = "openethereum";
+    rev = "v${version}";
+    sha256 = "08dkcrga1x18csh6pw6f54x5xwijppyjhg46cf4p452xc1l3a6ir";
+  };
+
+  cargoSha256 = "1xliragihwjfc5qmfm0ng519bw8a28m1w1yqcl9mpk8zywiybaah";
+
+  verifyCargoDeps = true;
+
+  cargoPatches = [ ./lock.patch ];
+
+  LIBCLANG_PATH = "${llvmPackages.libclang}/lib";
+  nativeBuildInputs = [
+    cmake
+    llvmPackages.clang
+    llvmPackages.libclang
+    pkg-config
+  ];
+
+  buildInputs = [ openssl systemd ];
+
+  cargoBuildFlags = [ "--features final" ];
+
+  # test result: FAILED. 88 passed; 13 failed; 0 ignored; 0 measured; 0 filtered out
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Fast, light, robust Ethereum implementation";
+    homepage = "http://parity.io/ethereum";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ akru xrelkd ];
+    platforms = platforms.linux;
+  };
+}

pkgs/applications/blockchains/openethereum/lock.patch

@@ -0,0 +1,20 @@
+--- /nix/store/hv764a65zmfzw5scjhz5839agv10da6x-source/Cargo.lock	1969-12-31 16:00:01.000000000 -0800
++++ ./Cargo.lock	2020-07-31 21:30:31.146750066 -0700
+@@ -3113,7 +3113,7 @@
+ 
+ [[package]]
+ name = "openethereum"
+-version = "3.0.0"
++version = "3.0.1"
+ dependencies = [
+  "ansi_term",
+  "atty",
+@@ -3562,7 +3562,7 @@
+ 
+ [[package]]
+ name = "parity-version"
+-version = "3.0.0"
++version = "3.0.1"
+ dependencies = [
+  "parity-bytes",
+  "rlp",