tomahawk: Add new package, version 0.8.1.

Although I've not tested the Tomahawk build on Mac OS X, it *should*
work on it, so I'm using platforms.all here.

Telepathy and KDE support are disabled by default in order to not get in
the way of users who want to use a more minimalistic window-manager-only
setup. But I'm not sure whether it matters in reality, we'll see once
more people are using Tomahawk.

Signed-off-by: aszlig <aszlig@redmoonstudios.org>

pkgs/applications/audio/tomahawk/default.nix

@@ -0,0 +1,46 @@
+{ stdenv, fetchurl, cmake, pkgconfig, attica, boost, gnutls, libechonest
+, liblastfm, lucenepp, phonon, qca2, qjson, qt4, qtkeychain, quazip, sparsehash
+, taglib, websocketpp
+
+, enableXMPP      ? true,  libjreen     ? null
+, enableKDE       ? false, kdelibs      ? null
+, enableTelepathy ? false, telepathy_qt ? null
+}:
+
+assert enableXMPP      -> libjreen     != null;
+assert enableKDE       -> kdelibs      != null;
+assert enableTelepathy -> telepathy_qt != null;
+
+let
+  quazipQt4 = quazip.override { qt = qt4; };
+in stdenv.mkDerivation rec {
+  name = "tomahawk-${version}";
+  version = "0.8.1";
+
+  src = fetchurl {
+    url = "http://download.tomahawk-player.org/tomahawk-0.8.1.tar.bz2";
+    sha256 = "0ca6fah30a2s8nnlryav95wyzhwys1ikjfwakrqf2hb0y5aczdpw";
+  };
+
+  cmakeFlags = [
+    "-DLUCENEPP_INCLUDE_DIR=${lucenepp}/include"
+    "-DLUCENEPP_LIBRARY_DIR=${lucenepp}/lib"
+  ];
+
+  buildInputs = [
+    cmake pkgconfig attica boost gnutls libechonest liblastfm lucenepp phonon
+    qca2 qjson qt4 qtkeychain quazipQt4 sparsehash taglib websocketpp
+  ] ++ stdenv.lib.optional enableXMPP      libjreen
+    ++ stdenv.lib.optional enableKDE       kdelibs
+    ++ stdenv.lib.optional enableTelepathy telepathy_qt;
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    description = "A multi-source music player";
+    homepage = "http://tomahawk-player.org/";
+    license = licenses.gpl3Plus;
+    platforms = platforms.all;
+    maintainers = [ maintainers.aszlig ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -10783,6 +10783,13 @@ let
 
   todo-txt-cli = callPackage ../applications/office/todo.txt-cli { };
 
+  tomahawk = callPackage ../applications/audio/tomahawk {
+    inherit (pkgs.kde4) kdelibs;
+    enableXMPP      = config.tomahawk.enableXMPP      or true;
+    enableKDE       = config.tomahawk.enableKDE       or false;
+    enableTelepathy = config.tomahawk.enableTelepathy or false;
+  };
+
   torchat = callPackage ../applications/networking/instant-messengers/torchat {
     wrapPython = pythonPackages.wrapPython;
   };