Mint-lang: Init at 2018.05.27

2018-05-27 22:09:09 +02:00
parent 3b5fd4dada
commit d6c4e3e8fb
4 changed files with 130 additions and 0 deletions
@@ -0,0 +1,59 @@
+{stdenv, lib, remarshal, runCommand, crystal, zlib, openssl, duktape}:
+let
+  crystalPackages = lib.mapAttrs (name: src:
+    stdenv.mkDerivation {
+      name = lib.replaceStrings ["/"] ["-"] name;
+      src = fetchGit src;
+      phases = "installPhase";
+      installPhase = ''cp -r $src $out'';
+      passthru = { libName = name; };
+    }
+  ) (import ./shards.nix);
+
+  crystalLib = stdenv.mkDerivation {
+    name = "crystal-lib";
+    src = lib.attrValues crystalPackages;
+    libNames = lib.mapAttrsToList (k: v: [k v]) crystalPackages;
+    phases = "buildPhase";
+    buildPhase = ''
+      mkdir -p $out
+      linkup () {
+        while [ "$#" -gt 0 ]; do
+          ln -s $2 $out/$1
+          shift; shift
+        done
+      }
+      linkup $libNames
+    '';
+  };
+in
+stdenv.mkDerivation rec {
+  version = "2018-05-27";
+  name = "mint-${version}";
+  src = fetchGit {
+    url = "https://github.com/mint-lang/mint.git";
+    rev = "a3f0c86f54b8b3a18dda5c39c2089bdb1d774b4f";
+  };
+
+  buildInputs = [ crystal zlib openssl duktape ];
+
+  buildPhase = ''
+    mkdir -p $out/bin
+
+    mkdir tmp
+    cd tmp
+    ln -s ${crystalLib} lib
+    cp -r $src/* .
+    crystal build src/mint.cr -o $out/bin/mint --verbose --progress --release --no-debug
+  '';
+
+  installPhase = ''true'';
+
+  meta = {
+    description = "A refreshing language for the front-end web.";
+    homepage = https://mint-lang.com/;
+    license = stdenv.lib.licenses.bsd3;
+    maintainers = with stdenv.lib.maintainers; [ manveru ];
+    platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" ];
+  };
+}