xfce.thunar-archive-plugin: init at 0.3.1 (close #10029)

A `thunar` plugin that adds archive manipulation features to
right click on file/directory menu. It can use either gnome or
kde archive managers. Detection of backend based on
`*.desktop` files mime types.

Should supercede non-functional pre-existing
`xfce.thunar_archive_plugin` (which for some
unknown reason is building the volume manager
plugin).

Also removed `xfce.thunar_archive_plugin` because
superceded.

Tests:

 -  When plugin package is installed, the supplementary
    menu entries appear in thunar.
 -  Succesfully extracted an archive using backend
    `file-roller` through thunar menu entry.

+ minor changes from vcunat, mainly meta.

pkgs/desktops/xfce/thunar-plugins/archive/default.nix

@@ -0,0 +1,58 @@
+{ stdenv, fetchFromGitHub, pkgconfig, xfce4_dev_tools
+, gtk
+, thunar
+, exo, libxfce4util, libxfce4ui
+, xfconf, udev, libnotify
+}:
+
+stdenv.mkDerivation rec {
+  p_name  = "thunar-archive-plugin";
+  ver_maj = "0.3";
+  ver_min = "1";
+  name = "${p_name}-${ver_maj}.${ver_min}";
+
+  src = fetchFromGitHub {
+    owner = "xfce-mirror";
+    repo = p_name;
+    rev = "72b23eefc348bee31e06a04f968e430bc7dfa51e";
+    sha256 = "0l8715x23qmk0jkywiza3qx0xxmafxi4grp7p82kkc5df5ccs8kx";
+  };
+
+  buildInputs = [
+    pkgconfig
+    xfce4_dev_tools
+    thunar
+    exo gtk libxfce4util libxfce4ui
+    xfconf udev libnotify
+  ];
+
+  preConfigure = ''
+    ./autogen.sh
+  '';
+
+  /*
+    File roller `*.desktop` situation
+    ---------------------------------
+
+    For some odd reason, in nix os, gnome file-roller's desktop file has the non-standard name
+    `org.gnome.FileRoller.desktop`. In order to be compatible with this odd context, create
+    a `*.tap` file of the same name.
+
+    IMPORTANT: Adapt or remove the symbolic link if the situation changes.
+  */
+  preFixup = ''
+    pushd $out/libexec/thunar-archive-plugin > /dev/null
+    ln -s ./file-roller.tap org.gnome.FileRoller.tap
+    popd > /dev/null
+    rm $out/share/icons/hicolor/icon-theme.cache
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    homepage = http://foo-projects.org/~benny/projects/thunar-archive-plugin/;
+    description = "Thunar plugin providing file context menus for archives";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+  };
+}