qt5: factor out common definitions and remove symlink farm
The module definitions are factored out and shared between qt56 and qt59. The symlink farm which was created during builds is no longer needed.
This commit is contained in:
Thomas Tuegel
@@ -0,0 +1,395 @@
|
||||
{
|
||||
stdenv, lib,
|
||||
src, patches, version, qtCompatVersion,
|
||||
|
||||
coreutils, bison, flex, gdb, gperf, lndir, patchelf, perl, pkgconfig, python2,
|
||||
ruby,
|
||||
# darwin support
|
||||
darwin, libiconv, libcxx,
|
||||
|
||||
dbus, fontconfig, freetype, glib, harfbuzz, icu, libX11, libXcomposite,
|
||||
libXcursor, libXext, libXi, libXrender, libinput, libjpeg, libpng, libtiff,
|
||||
libxcb, libxkbcommon, libxml2, libxslt, openssl, pcre16, pcre2, sqlite, udev,
|
||||
xcbutil, xcbutilimage, xcbutilkeysyms, xcbutilrenderutil, xcbutilwm, xlibs,
|
||||
zlib,
|
||||
|
||||
# optional dependencies
|
||||
cups ? null, mysql ? null, postgresql ? null,
|
||||
withGtk3 ? false, dconf ? null, gtk3 ? null,
|
||||
|
||||
# options
|
||||
mesaSupported ? (!stdenv.isDarwin),
|
||||
mesa,
|
||||
buildExamples ? false,
|
||||
buildTests ? false,
|
||||
developerBuild ? false,
|
||||
decryptSslTraffic ? false
|
||||
}:
|
||||
|
||||
assert withGtk3 -> dconf != null;
|
||||
assert withGtk3 -> gtk3 != null;
|
||||
|
||||
let
|
||||
system-x86_64 = lib.elem stdenv.system lib.platforms.x86_64;
|
||||
in
|
||||
|
||||
stdenv.mkDerivation {
|
||||
|
||||
name = "qtbase-${version}";
|
||||
inherit qtCompatVersion src version;
|
||||
|
||||
propagatedBuildInputs =
|
||||
[
|
||||
libxml2 libxslt openssl sqlite zlib
|
||||
|
||||
# Text rendering
|
||||
harfbuzz icu
|
||||
|
||||
# Image formats
|
||||
libjpeg libpng libtiff
|
||||
]
|
||||
++ (if builtins.compareVersions version "5.9.0" >= 0
|
||||
then [ pcre2 ] else [ pcre16 ])
|
||||
|
||||
++ lib.optional (mesaSupported && !stdenv.isDarwin) mesa
|
||||
|
||||
++ lib.optionals (!stdenv.isDarwin) [
|
||||
dbus glib udev
|
||||
|
||||
# Text rendering
|
||||
fontconfig freetype
|
||||
|
||||
# X11 libs
|
||||
libX11 libXcomposite libXext libXi libXrender libxcb libxkbcommon xcbutil
|
||||
xcbutilimage xcbutilkeysyms xcbutilrenderutil xcbutilwm
|
||||
]
|
||||
|
||||
++ lib.optionals stdenv.isDarwin (with darwin.apple_sdk.frameworks; [
|
||||
AGL AppKit ApplicationServices Carbon Cocoa
|
||||
CoreAudio CoreBluetooth CoreLocation CoreServices
|
||||
DiskArbitration Foundation OpenGL
|
||||
darwin.libobjc libiconv
|
||||
]);
|
||||
|
||||
buildInputs = [ ]
|
||||
++ lib.optional (!stdenv.isDarwin && withGtk3) gtk3
|
||||
++ lib.optional (!stdenv.isDarwin) libinput
|
||||
++ lib.optional developerBuild gdb
|
||||
++ lib.optional (cups != null) cups
|
||||
++ lib.optional (mysql != null) mysql.lib
|
||||
++ lib.optional (postgresql != null) postgresql;
|
||||
|
||||
nativeBuildInputs =
|
||||
[ bison flex gperf lndir perl pkgconfig python2 ]
|
||||
++ lib.optional (!stdenv.isDarwin) patchelf;
|
||||
|
||||
propagatedNativeBuildInputs = [ lndir ];
|
||||
|
||||
outputs = [ "bin" "dev" "out" ];
|
||||
|
||||
inherit patches;
|
||||
|
||||
fix_qt_static_libs = ../hooks/fix-qt-static-libs.sh;
|
||||
fix_qt_builtin_paths = ../hooks/fix-qt-builtin-paths.sh;
|
||||
fix_qt_module_paths = ../hooks/fix-qt-module-paths.sh;
|
||||
preHook = ''
|
||||
. "$fix_qt_static_libs"
|
||||
. "$fix_qt_builtin_paths"
|
||||
. "$fix_qt_module_paths"
|
||||
. ${../hooks/move-qt-dev-tools.sh}
|
||||
'';
|
||||
|
||||
postPatch =
|
||||
''
|
||||
for prf in qml_plugin.prf qt_plugin.prf qt_docs.prf qml_module.prf create_cmake.prf; do
|
||||
substituteInPlace "mkspecs/features/$prf" \
|
||||
--subst-var qtPluginPrefix \
|
||||
--subst-var qtQmlPrefix \
|
||||
--subst-var qtDocPrefix
|
||||
done
|
||||
|
||||
substituteInPlace configure --replace /bin/pwd pwd
|
||||
substituteInPlace src/corelib/global/global.pri --replace /bin/ls ${coreutils}/bin/ls
|
||||
sed -e 's@/\(usr\|opt\)/@/var/empty/@g' -i mkspecs/*/*.conf
|
||||
|
||||
sed -i '/PATHS.*NO_DEFAULT_PATH/ d' src/corelib/Qt5Config.cmake.in
|
||||
sed -i '/PATHS.*NO_DEFAULT_PATH/ d' src/corelib/Qt5CoreMacros.cmake
|
||||
sed -i 's/NO_DEFAULT_PATH//' src/gui/Qt5GuiConfigExtras.cmake.in
|
||||
sed -i '/PATHS.*NO_DEFAULT_PATH/ d' mkspecs/features/data/cmake/Qt5BasicConfig.cmake.in
|
||||
''
|
||||
|
||||
+ lib.optionalString (mesaSupported && !stdenv.isDarwin) ''
|
||||
sed -i mkspecs/common/linux.conf \
|
||||
-e "/^QMAKE_INCDIR_OPENGL/ s|$|${mesa.dev or mesa}/include|" \
|
||||
-e "/^QMAKE_LIBDIR_OPENGL/ s|$|${mesa.out}/lib|"
|
||||
''
|
||||
|
||||
+ lib.optionalString stdenv.isDarwin ''
|
||||
sed -i \
|
||||
-e 's|! /usr/bin/xcode-select --print-path >/dev/null 2>&1;|false;|' \
|
||||
-e 's|! /usr/bin/xcrun -find xcodebuild >/dev/null 2>&1;|false;|' \
|
||||
-e 's|sysroot=$(/usr/bin/xcodebuild -sdk $sdk -version Path 2>/dev/null)|sysroot=/nonsense|' \
|
||||
-e 's|sysroot=$(/usr/bin/xcrun --sdk $sdk --show-sdk-path 2>/dev/null)|sysroot=/nonsense|' \
|
||||
-e 's|QMAKE_CONF_COMPILER=`getXQMakeConf QMAKE_CXX`|QMAKE_CXX="clang++"\nQMAKE_CONF_COMPILER="clang++"|' \
|
||||
-e 's|XCRUN=`/usr/bin/xcrun -sdk macosx clang -v 2>&1`|XCRUN="clang -v 2>&1"|' \
|
||||
-e 's#sdk_val=$(/usr/bin/xcrun -sdk $sdk -find $(echo $val | cut -d \x27 \x27 -f 1))##' \
|
||||
-e 's#val=$(echo $sdk_val $(echo $val | cut -s -d \x27 \x27 -f 2-))##' \
|
||||
./configure
|
||||
substituteInPlace ./mkspecs/common/mac.conf \
|
||||
--replace "/System/Library/Frameworks/OpenGL.framework/" "${darwin.apple_sdk.frameworks.OpenGL}/Library/Frameworks/OpenGL.framework/"
|
||||
substituteInPlace ./mkspecs/common/mac.conf \
|
||||
--replace "/System/Library/Frameworks/AGL.framework/" "${darwin.apple_sdk.frameworks.AGL}/Library/Frameworks/AGL.framework/"
|
||||
'';
|
||||
# Note on the above: \x27 is a way if including a single-quote
|
||||
# character in the sed string arguments.
|
||||
|
||||
qtPluginPrefix = "lib/qt-${qtCompatVersion}/plugins";
|
||||
qtQmlPrefix = "lib/qt-${qtCompatVersion}/qml";
|
||||
qtDocPrefix = "share/doc/qt-${qtCompatVersion}";
|
||||
|
||||
setOutputFlags = false;
|
||||
preConfigure = ''
|
||||
export LD_LIBRARY_PATH="$PWD/lib:$PWD/plugins/platforms:$LD_LIBRARY_PATH"
|
||||
${lib.optionalString (builtins.compareVersions version "5.9.0" < 0) ''
|
||||
# We need to set LD to CXX or otherwise we get nasty compile errors
|
||||
export LD=$CXX
|
||||
''}
|
||||
|
||||
configureFlags+="\
|
||||
-plugindir $out/$qtPluginPrefix \
|
||||
-qmldir $out/$qtQmlPrefix \
|
||||
-docdir $out/$qtDocPrefix"
|
||||
|
||||
createQmakeCache() {
|
||||
cat >>"$1" <<EOF
|
||||
NIX_OUTPUT_BIN = $bin
|
||||
NIX_OUTPUT_DEV = $dev
|
||||
NIX_OUTPUT_OUT = $out
|
||||
NIX_OUTPUT_DOC = $dev/$qtDocPrefix
|
||||
NIX_OUTPUT_QML = $bin/$qtQmlPrefix
|
||||
NIX_OUTPUT_PLUGIN = $bin/$qtPluginPrefix
|
||||
EOF
|
||||
}
|
||||
|
||||
find . -name '.qmake.conf' | while read conf; do
|
||||
cache=$(dirname $conf)/.qmake.cache
|
||||
echo "Creating \`$cache'"
|
||||
createQmakeCache "$cache"
|
||||
done
|
||||
|
||||
NIX_CFLAGS_COMPILE+=" -DNIXPKGS_QT_PLUGIN_PREFIX=\"$qtPluginPrefix\""
|
||||
'';
|
||||
|
||||
|
||||
NIX_CFLAGS_COMPILE =
|
||||
[
|
||||
"-Wno-error=sign-compare" # freetype-2.5.4 changed signedness of some struct fields
|
||||
''-DNIXPKGS_QTCOMPOSE="${libX11.out}/share/X11/locale"''
|
||||
''-DNIXPKGS_LIBRESOLV="${stdenv.cc.libc.out}/lib/libresolv"''
|
||||
''-DNIXPKGS_LIBXCURSOR="${libXcursor.out}/lib/libXcursor"''
|
||||
]
|
||||
|
||||
++ lib.optional (mesaSupported && !stdenv.isDarwin)
|
||||
''-DNIXPKGS_MESA_GL="${mesa.out}/lib/libGL"''
|
||||
|
||||
++ lib.optionals (!stdenv.isDarwin && withGtk3)
|
||||
[
|
||||
''-DNIXPKGS_QGTK3_XDG_DATA_DIRS="${gtk3}/share/gsettings-schemas/${gtk3.name}"''
|
||||
''-DNIXPKGS_QGTK3_GIO_EXTRA_MODULES="${dconf.lib}/lib/gio/modules"''
|
||||
]
|
||||
|
||||
++ lib.optionals stdenv.isDarwin
|
||||
[
|
||||
"-Wno-missing-sysroot"
|
||||
"-D__MAC_OS_X_VERSION_MAX_ALLOWED=1090"
|
||||
"-D__AVAILABILITY_INTERNAL__MAC_10_10=__attribute__((availability(macosx,introduced=10.10)))"
|
||||
# Note that nixpkgs's objc4 is from macOS 10.11 while the SDK is
|
||||
# 10.9 which necessitates the above macro definition that mentions
|
||||
# 10.10
|
||||
]
|
||||
|
||||
++ lib.optional decryptSslTraffic "-DQT_DECRYPT_SSL_TRAFFIC";
|
||||
|
||||
prefixKey = "-prefix ";
|
||||
|
||||
# PostgreSQL autodetection fails sporadically because Qt omits the "-lpq" flag
|
||||
# if dependency paths contain the string "pq", which can occur in the hash.
|
||||
# To prevent these failures, we need to override PostgreSQL detection.
|
||||
PSQL_LIBS = lib.optionalString (postgresql != null) "-L${postgresql.lib}/lib -lpq";
|
||||
|
||||
# -no-eglfs, -no-directfb, -no-linuxfb and -no-kms because of the current minimalist mesa
|
||||
# TODO Remove obsolete and useless flags once the build will be totally mastered
|
||||
configureFlags =
|
||||
[
|
||||
"-verbose"
|
||||
"-confirm-license"
|
||||
"-opensource"
|
||||
|
||||
"-release"
|
||||
"-shared"
|
||||
"-accessibility"
|
||||
"-optimized-qmake"
|
||||
"-strip"
|
||||
"-system-proxies"
|
||||
"-pkg-config"
|
||||
]
|
||||
++ lib.optionals (builtins.compareVersions version "5.9.0" < 0)
|
||||
[
|
||||
"-c++11"
|
||||
"-no-reduce-relocations"
|
||||
]
|
||||
++ lib.optionals developerBuild [
|
||||
"-developer-build"
|
||||
"-no-warnings-are-errors"
|
||||
]
|
||||
++ [
|
||||
"-gui"
|
||||
"-widgets"
|
||||
"-opengl desktop"
|
||||
"-qml-debug"
|
||||
"-icu"
|
||||
"-pch"
|
||||
]
|
||||
|
||||
++ (if builtins.compareVersions version "5.9.0" >= 0
|
||||
then [ (if system-x86_64 then "-sse2" else "-no-sse2") ]
|
||||
else lib.optional (!system-x86_64) "-no-sse2")
|
||||
++ [
|
||||
"-no-sse3"
|
||||
"-no-ssse3"
|
||||
"-no-sse4.1"
|
||||
"-no-sse4.2"
|
||||
"-no-avx"
|
||||
"-no-avx2"
|
||||
"-no-mips_dsp"
|
||||
"-no-mips_dspr2"
|
||||
]
|
||||
|
||||
++ [
|
||||
"-system-zlib"
|
||||
"-system-libjpeg"
|
||||
"-system-harfbuzz"
|
||||
"-system-pcre"
|
||||
"-openssl-linked"
|
||||
"-system-sqlite"
|
||||
''-${if mysql != null then "plugin" else "no"}-sql-mysql''
|
||||
''-${if postgresql != null then "plugin" else "no"}-sql-psql''
|
||||
|
||||
"-make libs"
|
||||
"-make tools"
|
||||
''-${lib.optionalString (buildExamples == false) "no"}make examples''
|
||||
''-${lib.optionalString (buildTests == false) "no"}make tests''
|
||||
"-v"
|
||||
]
|
||||
|
||||
++ lib.optionals (!stdenv.isDarwin) [
|
||||
"-${lib.optionalString (builtins.compareVersions version "5.9.0" < 0) "no-"}rpath"
|
||||
|
||||
"-system-xcb"
|
||||
"-xcb"
|
||||
"-qpa xcb"
|
||||
|
||||
"-system-xkbcommon"
|
||||
"-libinput"
|
||||
"-xkbcommon-evdev"
|
||||
|
||||
"-no-eglfs"
|
||||
"-no-gbm"
|
||||
"-no-kms"
|
||||
"-no-linuxfb"
|
||||
|
||||
''-${lib.optionalString (cups == null) "no-"}cups''
|
||||
"-dbus-linked"
|
||||
"-glib"
|
||||
"-system-libjpeg"
|
||||
"-system-libpng"
|
||||
# gold linker of binutils 2.28 generates duplicate symbols
|
||||
# TODO: remove for newer version of binutils
|
||||
"-no-use-gold-linker"
|
||||
]
|
||||
++ lib.optional withGtk3 "-gtk"
|
||||
++ lib.optional (builtins.compareVersions version "5.9.0" >= 0) "-inotify"
|
||||
|
||||
++ lib.optionals stdenv.isDarwin [
|
||||
"-platform macx-clang"
|
||||
"-no-use-gold-linker"
|
||||
"-no-fontconfig"
|
||||
"-qt-freetype"
|
||||
"-qt-libpng"
|
||||
];
|
||||
|
||||
enableParallelBuilding = true;
|
||||
|
||||
postInstall =
|
||||
# Move selected outputs.
|
||||
''
|
||||
moveToOutput "mkspecs" "$dev"
|
||||
'';
|
||||
|
||||
devTools = [
|
||||
"bin/fixqt4headers.pl"
|
||||
"bin/moc"
|
||||
"bin/qdbuscpp2xml"
|
||||
"bin/qdbusxml2cpp"
|
||||
"bin/qlalr"
|
||||
"bin/qmake"
|
||||
"bin/rcc"
|
||||
"bin/syncqt.pl"
|
||||
"bin/uic"
|
||||
];
|
||||
|
||||
postFixup =
|
||||
# Don't retain build-time dependencies like gdb.
|
||||
''
|
||||
sed '/QMAKE_DEFAULT_.*DIRS/ d' -i $dev/mkspecs/qconfig.pri
|
||||
''
|
||||
|
||||
+ ''
|
||||
fixQtModulePaths "''${!outputDev}/mkspecs/modules"
|
||||
fixQtBuiltinPaths "''${!outputDev}" '*.pr?'
|
||||
''
|
||||
|
||||
# Move static libraries and QMake library definitions into $dev.
|
||||
+ ''
|
||||
fixQtStaticLibs "''${!outputLib}" "''${!outputDev}"
|
||||
''
|
||||
|
||||
# Move development tools to $dev
|
||||
+ ''
|
||||
moveQtDevTools
|
||||
moveToOutput bin "$dev"
|
||||
''
|
||||
|
||||
# fixup .pc file (where to find 'moc' etc.)
|
||||
+ lib.optionalString (!stdenv.isDarwin) ''
|
||||
sed -i "$dev/lib/pkgconfig/Qt5Core.pc" \
|
||||
-e "/^host_bins=/ c host_bins=$dev/bin"
|
||||
''
|
||||
|
||||
+ lib.optionalString stdenv.isDarwin ''
|
||||
fixDarwinDylibNames_rpath() {
|
||||
local flags=()
|
||||
|
||||
for fn in "$@"; do
|
||||
flags+=(-change "@rpath/$fn.framework/Versions/5/$fn" "$out/lib/$fn.framework/Versions/5/$fn")
|
||||
done
|
||||
|
||||
for fn in "$@"; do
|
||||
echo "$fn: fixing dylib"
|
||||
install_name_tool -id "$out/lib/$fn.framework/Versions/5/$fn" "''${flags[@]}" "$out/lib/$fn.framework/Versions/5/$fn"
|
||||
done
|
||||
}
|
||||
fixDarwinDylibNames_rpath "QtConcurrent" "QtPrintSupport" "QtCore" "QtSql" "QtDBus" "QtTest" "QtGui" "QtWidgets" "QtNetwork" "QtXml" "QtOpenGL"
|
||||
'';
|
||||
|
||||
setupHook = ../hooks/qtbase-setup-hook.sh;
|
||||
|
||||
meta = with lib; {
|
||||
homepage = http://www.qt.io;
|
||||
description = "A cross-platform application framework for C++";
|
||||
license = with licenses; [ fdl13 gpl2 lgpl21 lgpl3 ];
|
||||
maintainers = with maintainers; [ qknight ttuegel periklis ];
|
||||
platforms = platforms.unix;
|
||||
};
|
||||
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtbase, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtcharts";
|
||||
qtInputs = [ qtbase qtdeclarative ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
@@ -0,0 +1,8 @@
|
||||
{ qtModule, qtbase, qtdeclarative, bluez }:
|
||||
|
||||
qtModule {
|
||||
name = "qtconnectivity";
|
||||
qtInputs = [ qtbase qtdeclarative ];
|
||||
buildInputs = [ bluez ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
@@ -0,0 +1,25 @@
|
||||
{ qtModule, lib, python2, qtbase, qtsvg, qtxmlpatterns }:
|
||||
|
||||
with lib;
|
||||
|
||||
qtModule {
|
||||
name = "qtdeclarative";
|
||||
qtInputs = [ qtbase qtsvg qtxmlpatterns ];
|
||||
nativeBuildInputs = [ python2 ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
preConfigure = ''
|
||||
NIX_CFLAGS_COMPILE+=" -DNIXPKGS_QML2_IMPORT_PREFIX=\"$qtQmlPrefix\""
|
||||
'';
|
||||
devTools = [
|
||||
"bin/qml"
|
||||
"bin/qmlcachegen"
|
||||
"bin/qmleasing"
|
||||
"bin/qmlimportscanner"
|
||||
"bin/qmllint"
|
||||
"bin/qmlmin"
|
||||
"bin/qmlplugindump"
|
||||
"bin/qmlprofiler"
|
||||
"bin/qmlscene"
|
||||
"bin/qmltestrunner"
|
||||
];
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtdoc";
|
||||
qtInputs = [ qtdeclarative ];
|
||||
outputs = [ "out" ];
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtgraphicaleffects";
|
||||
qtInputs = [ qtdeclarative ];
|
||||
outputs = [ "out" ];
|
||||
}
|
||||
@@ -0,0 +1,6 @@
|
||||
{ qtModule, qtbase }:
|
||||
|
||||
qtModule {
|
||||
name = "qtimageformats";
|
||||
qtInputs = [ qtbase ];
|
||||
}
|
||||
@@ -0,0 +1,9 @@
|
||||
{ qtModule, qtbase, qtmultimedia }:
|
||||
|
||||
qtModule {
|
||||
name = "qtlocation";
|
||||
qtInputs = [ qtbase qtmultimedia ];
|
||||
outputs = [ "bin" "out" "dev" ];
|
||||
# Linking with -lclipper fails with parallel build enabled
|
||||
enableParallelBuilding = false;
|
||||
}
|
||||
@@ -0,0 +1,10 @@
|
||||
{ qtModule, qtbase, lib }:
|
||||
|
||||
qtModule {
|
||||
name = "qtmacextras";
|
||||
qtInputs = [ qtbase ];
|
||||
meta = with lib; {
|
||||
maintainers = with maintainers; [ periklis ];
|
||||
platforms = platforms.darwin;
|
||||
};
|
||||
}
|
||||
@@ -0,0 +1,17 @@
|
||||
{ qtModule, stdenv, qtbase, qtdeclarative, pkgconfig
|
||||
, alsaLib, gstreamer, gst-plugins-base, libpulseaudio
|
||||
, darwin
|
||||
}:
|
||||
|
||||
with stdenv.lib;
|
||||
|
||||
qtModule {
|
||||
name = "qtmultimedia";
|
||||
qtInputs = [ qtbase qtdeclarative ];
|
||||
nativeBuildInputs = [ pkgconfig ];
|
||||
buildInputs = [ gstreamer gst-plugins-base libpulseaudio]
|
||||
++ optional (stdenv.isLinux) alsaLib;
|
||||
outputs = [ "bin" "dev" "out" ];
|
||||
qmakeFlags = [ "GST_VERSION=1.0" ];
|
||||
NIX_LDFLAGS = optionalString (stdenv.isDarwin) "-lobjc";
|
||||
}
|
||||
@@ -0,0 +1,6 @@
|
||||
{ qtModule, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtquickcontrols";
|
||||
qtInputs = [ qtdeclarative ];
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtquickcontrols2";
|
||||
qtInputs = [ qtdeclarative ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
@@ -0,0 +1,6 @@
|
||||
{ qtModule, qtbase, qttools }:
|
||||
|
||||
qtModule {
|
||||
name = "qtscript";
|
||||
qtInputs = [ qtbase qttools ];
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtbase, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtsensors";
|
||||
qtInputs = [ qtbase qtdeclarative ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
@@ -0,0 +1,11 @@
|
||||
{ qtModule, stdenv, lib, qtbase, substituteAll, systemd }:
|
||||
|
||||
let inherit (lib) getLib optional; in
|
||||
|
||||
qtModule {
|
||||
name = "qtserialport";
|
||||
qtInputs = [ qtbase ];
|
||||
NIX_CFLAGS_COMPILE =
|
||||
optional stdenv.isLinux
|
||||
''-DNIXPKGS_LIBUDEV="${getLib systemd}/lib/libudev"'';
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtbase }:
|
||||
|
||||
qtModule {
|
||||
name = "qtsvg";
|
||||
qtInputs = [ qtbase ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
@@ -0,0 +1,34 @@
|
||||
{ qtModule, lib, qtbase }:
|
||||
|
||||
with lib;
|
||||
|
||||
qtModule {
|
||||
name = "qttools";
|
||||
qtInputs = [ qtbase ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
|
||||
# fixQtBuiltinPaths overwrites a builtin path we should keep
|
||||
postPatch = ''
|
||||
sed -i "src/linguist/linguist.pro" \
|
||||
-e '/^cmake_linguist_config_version_file.input =/ s|$$\[QT_HOST_DATA.*\]|${getDev qtbase}|'
|
||||
'';
|
||||
|
||||
devTools = [
|
||||
"bin/qcollectiongenerator"
|
||||
"bin/linguist"
|
||||
"bin/assistant"
|
||||
"bin/qdoc"
|
||||
"bin/lconvert"
|
||||
"bin/designer"
|
||||
"bin/qtattributesscanner"
|
||||
"bin/lrelease"
|
||||
"bin/pixeltool"
|
||||
"bin/lupdate"
|
||||
"bin/qtdiag"
|
||||
"bin/qhelpgenerator"
|
||||
"bin/qtplugininfo"
|
||||
"bin/qthelpconverter"
|
||||
];
|
||||
|
||||
setupHook = ../hooks/qttools-setup-hook.sh;
|
||||
}
|
||||
@@ -0,0 +1,6 @@
|
||||
{ qtModule, qttools }:
|
||||
|
||||
qtModule {
|
||||
name = "qttranslations";
|
||||
qtInputs = [ qttools ];
|
||||
}
|
||||
@@ -0,0 +1,9 @@
|
||||
{ qtModule, qtbase, qtquickcontrols, wayland, pkgconfig }:
|
||||
|
||||
qtModule {
|
||||
name = "qtwayland";
|
||||
qtInputs = [ qtbase qtquickcontrols ];
|
||||
buildInputs = [ wayland ];
|
||||
nativeBuildInputs = [ pkgconfig ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
@@ -0,0 +1,8 @@
|
||||
{ qtModule, qtbase, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtwebchannel";
|
||||
qtInputs = [ qtbase qtdeclarative ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
|
||||
@@ -0,0 +1,121 @@
|
||||
{ qtModule, qtCompatVersion,
|
||||
qtdeclarative, qtquickcontrols, qtlocation, qtwebchannel
|
||||
|
||||
, bison, coreutils, flex, git, gperf, ninja, pkgconfig, python2, which
|
||||
|
||||
, xlibs, libXcursor, libXScrnSaver, libXrandr, libXtst
|
||||
, fontconfig, freetype, harfbuzz, icu, dbus
|
||||
, zlib, minizip, libjpeg, libpng, libtiff, libwebp, libopus
|
||||
, jsoncpp, protobuf, libvpx, srtp, snappy, nss, libevent
|
||||
, alsaLib
|
||||
, libcap
|
||||
, pciutils
|
||||
, systemd
|
||||
|
||||
, enableProprietaryCodecs ? true
|
||||
|
||||
, lib, stdenv # lib.optional, needsPax
|
||||
}:
|
||||
|
||||
with stdenv.lib;
|
||||
|
||||
let qt56 = qtCompatVersion == "5.6"; in
|
||||
|
||||
qtModule {
|
||||
name = "qtwebengine";
|
||||
qtInputs = [ qtdeclarative qtquickcontrols qtlocation qtwebchannel ];
|
||||
nativeBuildInputs = [
|
||||
bison coreutils flex git gperf ninja pkgconfig python2 which
|
||||
];
|
||||
doCheck = true;
|
||||
outputs = [ "bin" "dev" "out" ];
|
||||
|
||||
enableParallelBuilding = true;
|
||||
|
||||
postPatch =
|
||||
# Patch Chromium build tools
|
||||
''
|
||||
( cd src/3rdparty/chromium; patchShebangs . )
|
||||
''
|
||||
# Patch Chromium build files
|
||||
+ ''
|
||||
substituteInPlace ./src/3rdparty/chromium/build/common.gypi \
|
||||
--replace /bin/echo ${coreutils}/bin/echo
|
||||
substituteInPlace ./src/3rdparty/chromium/v8/${if qt56 then "build" else "gypfiles"}/toolchain.gypi \
|
||||
--replace /bin/echo ${coreutils}/bin/echo
|
||||
substituteInPlace ./src/3rdparty/chromium/v8/${if qt56 then "build" else "gypfiles"}/standalone.gypi \
|
||||
--replace /bin/echo ${coreutils}/bin/echo
|
||||
''
|
||||
# Patch library paths in Qt sources
|
||||
+ ''
|
||||
sed -i \
|
||||
-e "s,QLibraryInfo::location(QLibraryInfo::DataPath),QLatin1String(\"$out\"),g" \
|
||||
-e "s,QLibraryInfo::location(QLibraryInfo::TranslationsPath),QLatin1String(\"$out/translations\"),g" \
|
||||
-e "s,QLibraryInfo::location(QLibraryInfo::LibraryExecutablesPath),QLatin1String(\"$out/libexec\"),g" \
|
||||
src/core/web_engine_library_info.cpp
|
||||
''
|
||||
# Patch library paths in Chromium sources
|
||||
+ optionalString (!stdenv.isDarwin) ''
|
||||
sed -i -e '/lib_loader.*Load/s!"\(libudev\.so\)!"${systemd.lib}/lib/\1!' \
|
||||
src/3rdparty/chromium/device/udev_linux/udev?_loader.cc
|
||||
|
||||
sed -i -e '/libpci_loader.*Load/s!"\(libpci\.so\)!"${pciutils}/lib/\1!' \
|
||||
src/3rdparty/chromium/gpu/config/gpu_info_collector_linux.cc
|
||||
'';
|
||||
|
||||
preConfigure = ''
|
||||
export MAKEFLAGS=-j$NIX_BUILD_CORES
|
||||
|
||||
if [ -d "$PWD/tools/qmake" ]; then
|
||||
QMAKEPATH="$PWD/tools/qmake''${QMAKEPATH:+:}$QMAKEPATH"
|
||||
fi
|
||||
'';
|
||||
|
||||
qmakeFlags =
|
||||
[
|
||||
# Use system Ninja because bootstrapping it is fragile
|
||||
"WEBENGINE_CONFIG+=use_system_ninja"
|
||||
] ++ optional enableProprietaryCodecs "WEBENGINE_CONFIG+=use_proprietary_codecs";
|
||||
|
||||
propagatedBuildInputs = [
|
||||
# Image formats
|
||||
libjpeg libpng libtiff libwebp
|
||||
|
||||
# Video formats
|
||||
srtp libvpx
|
||||
|
||||
# Audio formats
|
||||
libopus
|
||||
|
||||
# Text rendering
|
||||
harfbuzz icu
|
||||
]
|
||||
++ optionals (!stdenv.isDarwin) [
|
||||
dbus zlib minizip snappy nss protobuf jsoncpp libevent
|
||||
|
||||
# Audio formats
|
||||
alsaLib
|
||||
|
||||
# Text rendering
|
||||
fontconfig freetype
|
||||
|
||||
libcap
|
||||
pciutils
|
||||
|
||||
# X11 libs
|
||||
xlibs.xrandr libXScrnSaver libXcursor libXrandr xlibs.libpciaccess libXtst
|
||||
xlibs.libXcomposite
|
||||
];
|
||||
|
||||
dontUseNinjaBuild = true;
|
||||
dontUseNinjaInstall = true;
|
||||
|
||||
postInstall = ''
|
||||
cat > $out/libexec/qt.conf <<EOF
|
||||
[Paths]
|
||||
Prefix = ..
|
||||
EOF
|
||||
|
||||
paxmark m $out/libexec/QtWebEngineProcess
|
||||
'';
|
||||
}
|
||||
@@ -0,0 +1,45 @@
|
||||
{ qtModule, stdenv, lib
|
||||
, qtbase, qtdeclarative, qtlocation, qtsensors
|
||||
, fontconfig, gdk_pixbuf, gtk2, libwebp, libxml2, libxslt
|
||||
, sqlite, systemd, glib, gst_all_1
|
||||
, bison2, flex, gdb, gperf, perl, pkgconfig, python2, ruby
|
||||
, darwin
|
||||
, substituteAll
|
||||
, flashplayerFix ? false
|
||||
}:
|
||||
|
||||
let inherit (lib) optional optionals getLib; in
|
||||
|
||||
qtModule {
|
||||
name = "qtwebkit";
|
||||
qtInputs = [ qtbase qtdeclarative qtlocation qtsensors ];
|
||||
buildInputs = [ fontconfig libwebp libxml2 libxslt sqlite glib gst_all_1.gstreamer gst_all_1.gst-plugins-base ]
|
||||
++ optionals (stdenv.isDarwin) (with darwin.apple_sdk.frameworks; [ OpenGL ]);
|
||||
nativeBuildInputs = [
|
||||
bison2 flex gdb gperf perl pkgconfig python2 ruby
|
||||
];
|
||||
|
||||
__impureHostDeps = optionals (stdenv.isDarwin) [
|
||||
"/usr/lib/libicucore.dylib"
|
||||
];
|
||||
|
||||
# QtWebKit overrides qmake's default_pre and default_post features,
|
||||
# so its custom qmake files must be found first at the front of QMAKEPATH.
|
||||
preConfigure = ''
|
||||
QMAKEPATH="$PWD/Tools/qmake''${QMAKEPATH:+:}$QMAKEPATH"
|
||||
fixQtBuiltinPaths . '*.pr?'
|
||||
'';
|
||||
|
||||
NIX_CFLAGS_COMPILE =
|
||||
optionals flashplayerFix
|
||||
[
|
||||
''-DNIXPKGS_LIBGTK2="${getLib gtk2}/lib/libgtk-x11-2.0"''
|
||||
''-DNIXPKGS_LIBGDK2="${getLib gdk_pixbuf}/lib/libgdk-x11-2.0"''
|
||||
]
|
||||
++ optional (!stdenv.isDarwin) ''-DNIXPKGS_LIBUDEV="${getLib systemd}/lib/libudev"'';
|
||||
|
||||
# Hack to avoid TMPDIR in RPATHs.
|
||||
preFixup = ''rm -rf "$(pwd)" && mkdir "$(pwd)" '';
|
||||
|
||||
meta.maintainers = with stdenv.lib.maintainers; [ abbradar periklis ];
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtbase, qtdeclarative }:
|
||||
|
||||
qtModule {
|
||||
name = "qtwebsockets";
|
||||
qtInputs = [ qtbase qtdeclarative ];
|
||||
outputs = [ "out" "dev" "bin" ];
|
||||
}
|
||||
@@ -0,0 +1,6 @@
|
||||
{ qtModule, qtbase }:
|
||||
|
||||
qtModule {
|
||||
name = "qtx11extras";
|
||||
qtInputs = [ qtbase ];
|
||||
}
|
||||
@@ -0,0 +1,7 @@
|
||||
{ qtModule, qtbase }:
|
||||
|
||||
qtModule {
|
||||
name = "qtxmlpatterns";
|
||||
qtInputs = [ qtbase ];
|
||||
devTools = [ "bin/xmlpatterns" "bin/xmlpatternsvalidator" ];
|
||||
}
|
||||
Reference in New Issue
Block a user