Maximilian Bosch
1eb5ab963a
ChangeLog: https://github.com/getferdi/ferdi/blob/1886c8abed32e33f0f547c069c674b79279cf931/CHANGELOG.md#560-beta6-2021-05-31 Even though this isn't explicitly noted in the Changelog, this seems to have fixed the Element integration for me. Additionally, I added a (hacky) `xdg-open` wrapper which removes the `GDK_BACKEND` variable to fix the XWayland integration[1]. The problem is that if a Firefox is running with Wayland (`ferdi` is running under X11) and `GDK_BACKEND=x11` is passed to the `xdg-open` (and thus `firefox`) process, Firefox refuses to start since another instance of it is running under Wayland (but attempts to start in X11 mode because of `GDK_BACKEND=x11`). [1] https://github.com/electron/electron/issues/28436 (cherry picked from commit cd4ad7d2fee90fc3afb9f3f3957a7289f02f89dc)
95 lines
1.6 KiB
Nix
95 lines
1.6 KiB
Nix
{ stdenv
|
|
, lib
|
|
, makeWrapper
|
|
, wrapGAppsHook
|
|
, autoPatchelfHook
|
|
, dpkg
|
|
, xorg
|
|
, atk
|
|
, glib
|
|
, pango
|
|
, gdk-pixbuf
|
|
, cairo
|
|
, freetype
|
|
, fontconfig
|
|
, gtk3
|
|
, gnome2
|
|
, dbus
|
|
, nss
|
|
, nspr
|
|
, alsaLib
|
|
, cups
|
|
, expat
|
|
, udev
|
|
, libnotify
|
|
, xdg-utils
|
|
, mesa
|
|
}:
|
|
|
|
# Helper function for building a derivation for Franz and forks.
|
|
|
|
{ pname, name, version, src, meta, extraBuildInputs ? [] }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
inherit pname version src meta;
|
|
|
|
# Don't remove runtime deps.
|
|
dontPatchELF = true;
|
|
|
|
nativeBuildInputs = [ autoPatchelfHook makeWrapper wrapGAppsHook dpkg ];
|
|
buildInputs = extraBuildInputs ++ (with xorg; [
|
|
libXi
|
|
libXcursor
|
|
libXdamage
|
|
libXrandr
|
|
libXcomposite
|
|
libXext
|
|
libXfixes
|
|
libXrender
|
|
libX11
|
|
libXtst
|
|
libXScrnSaver
|
|
]) ++ [
|
|
mesa #libgbm
|
|
gtk3
|
|
atk
|
|
glib
|
|
pango
|
|
gdk-pixbuf
|
|
cairo
|
|
freetype
|
|
fontconfig
|
|
dbus
|
|
gnome2.GConf
|
|
nss
|
|
nspr
|
|
alsaLib
|
|
cups
|
|
expat
|
|
stdenv.cc.cc
|
|
];
|
|
runtimeDependencies = [ stdenv.cc.cc.lib (lib.getLib udev) libnotify ];
|
|
|
|
unpackPhase = "dpkg-deb -x $src .";
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin
|
|
cp -r opt $out
|
|
ln -s $out/opt/${name}/${pname} $out/bin
|
|
|
|
# Provide desktop item and icon.
|
|
cp -r usr/share $out
|
|
substituteInPlace $out/share/applications/${pname}.desktop \
|
|
--replace /opt/${name}/${pname} ${pname}
|
|
'';
|
|
|
|
dontWrapGApps = true;
|
|
|
|
postFixup = ''
|
|
wrapProgram $out/opt/${name}/${pname} \
|
|
--prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath runtimeDependencies}" \
|
|
--prefix PATH : ${xdg-utils}/bin \
|
|
"''${gappsWrapperArgs[@]}"
|
|
'';
|
|
}
|